/begin-procedure log=*a,par=*y(proc-par=(                              -
/        &INBUILD1=TRMV761.TNMNAT31.WEB1,                               -
/        &INBUILD2=TRMV761.TNMNAT31.WEB2,                               -
/        &INBUILD3=TRMV761.TNMNAT31.WEB3,                               -
/        &INDDE=TRMV761.DDE.WEB,                                       -
/        &INFDT=TRMV761.TNMFILE.WEB,                                   -
/        &OUTBUILD=TRMTNM.BUILD,                                       -
/        &OUTDDE=TRMTNM.DDE,                                           -
/        &OUTFDT=TRMTNM.TNMFILE,                                       -
/        &TRMLIB=TRMLIB.V761                                           -
/        ))
/modify-terminal-options overflow-control=*no-control
/REMARK --------------------------------------------------------------*
/REMARK This proc converts the encoded (downloadable) TRM 'BUILD' and
/REMARK verification files back to their original (decoded) form.  The
/REMARK 'BUILD' file is also converted from 3 files to a single file.
/REMARK &&INBUILDx - The three input (encoded) BUILD file names.
/REMARK &&INDDE    - The input (encoded) NATURAL DDE
/REMARK &&INFDT    - The input (encoded) ADABAS FDT
/REMARK &&OUTBUILD - The output BUILD file name.
/REMARK &&OUTDDE   - The output DDE file name.
/REMARK &&OUTFDT   - The output FDT file name.
/REMARK &&TRMLIB   - The library containing the TSIGENER utility.
/REMARK --------------------------------------------------------------*
/assign-syslst p.TRMdecbu.lst
/mod-job-opt   logging=*par(listing=*yes)
/assign-sysdta *syscmd
/REMARK --------------------------------------------------------------*
/REMARK --------- Delete files that we create
/REMARK --------------------------------------------------------------*
/delete-file   file-name=&OUTBUILD
/set-job-step
/delete-file   file-name=&OUTDDE
/set-job-step
/delete-file   file-name=&OUTFDT
/set-job-step
/REMARK --------------------------------------------------------------*
/REMARK --------- Decode the 3 build files back to a single file
/REMARK --------------------------------------------------------------*
/create-file   file-name=&OUTBUILD,                                    -
/              support=*public-disk(space=*relative(primary-alloc=50,  -
/              secondary-alloc=50))
/add-file-link link-name=IN1,file-name=&INBUILD1,                      -
/              open-mode=*input,record-size=84
/add-file-link link-name=IN2,file-name=&INBUILD2,                      -
/              open-mode=*input,record-size=84
/add-file-link link-name=IN3,file-name=&INBUILD3,                      -
/              open-mode=*input,record-size=84
/add-file-link link-name=OUT1,file-name=&OUTBUILD,                     -
/              open-mode=*output,record-format=*var,                   -
/              record-size=32760,buffer-length=*std(16),               -
/              access-method=*sam
/start-program from-file=*module(lib=&TRMLIB,elem=TSIGENER,            -
/              run-mode=*advanced)
//decode
//input-files 3
//copy
/set-job-step
/REMARK --------------------------------------------------------------*
/REMARK --------- Decode the FDT file
/REMARK --------------------------------------------------------------*
/create-file   file-name=&OUTFDT,                                      -
/              support=*public-disk(space=*relative(primary-alloc=50,  -
/              secondary-alloc=50))
/add-file-link link-name=IN1,file-name=&INFDT,                         -
/              open-mode=*input,record-size=84
/add-file-link link-name=OUT1,file-name=&OUTFDT,                       -
/              open-mode=*output,record-format=*var,                   -
/              record-size=9996,buffer-length=*std(16),                -
/              access-method=*sam
/start-program from-file=*module(lib=&TRMLIB,elem=TSIGENER,            -
/              run-mode=*advanced)
//decode
//input-files 1
//copy
/set-job-step
/REMARK --------------------------------------------------------------*
/REMARK --------- Decode the DDE file
/REMARK --------------------------------------------------------------*
/create-file   file-name=&OUTDDE,                                      -
/              support=*public-disk(space=*relative(primary-alloc=50,  -
/              secondary-alloc=50))
/add-file-link link-name=IN1,file-name=&INDDE,                         -
/              open-mode=*input,record-size=84
/add-file-link link-name=OUT1,file-name=&OUTDDE,                       -
/              open-mode=*output,record-format=*var,                   -
/              record-size=9996,buffer-length=*std(16),                -
/              access-method=*sam
/start-program from-file=*module(lib=&TRMLIB,elem=TSIGENER,            -
/              run-mode=*advanced)
//decode
//input-files 1
//copy
/set-job-step
/modify-terminal-options overflow-control=*user-acknowledge
/assign-syslst *prim
/assign-sysdta *prim
/end-procedure